use AnyEvent::IO;
# load /etc/passwd, call callback with the file data when done.
aio_load "/etc/passwd", sub {
my ($data) = @_
or return AE::log error => "/etc/passwd: $!";
warn "/etc/passwd contains ", ($data =~ y/://) , " colons.\n";
};
# the rest of the SYNOPSIS does the same, but with individual I/O calls
# also import O_XXX flags
use AnyEvent::IO qw(:DEFAULT :flags);
my $filedata = AE::cv;
# first open the file
aio_open "/etc/passwd", O_RDONLY, 0, sub {
my ($fh) = @_
or return AE::log error => "/etc/passwd: $!";
# now stat the file to get the size
aio_stat $fh, sub {
@_
or return AE::log error => "/etc/passwd: $!";
my $size = -s _;
# now read all the file data
aio_read $fh, $size, sub {
my ($data) = @_
or return AE::log error => "/etc/passwd: $!";
$size == length $data
or return AE::log error => "/etc/passwd: short read, file changed?";
# mostly the same as aio_load, above - $data contains
# the file contents now.
$filedata->($data);
};
};
};
my $passwd = $filedata->recv;
warn length $passwd, " octets.\n";
The only other implementation that is supported (or even known to the author) is IO::AIO, which is used automatically when it can be loaded (via AnyEvent::AIO, which also needs to be installed). If it is not available, then AnyEvent::IO falls back to its synchronous pure-perl implementation.
Unlike AnyEvent, which model to use is currently decided at module load time, not at first use. Future releases might change this.
Whatever the situation, some programs just can't afford to block for long times (say, half a second or more), because they need to respond as fast as possible.
For those cases, you need asynchronous I/O.
The problem is, AnyEvent itself sometimes reads disk files (for example, when looking at /etc/hosts), and under the above situations, this can bring your program to a complete halt even if your program otherwise takes care to only use asynchronous I/O for everything (e.g. by using IO::AIO).
On the other hand, requiring IO::AIO for AnyEvent is clearly impossible, as AnyEvent promises to stay pure-perl, and the overhead of IO::AIO for small programs would be immense, especially when asynchronous I/O isn't even needed.
Clearly, this calls for an abstraction layer, and that is what you are looking at right now :-)
Non-blocking I/O means that data is delivered by some external means, automatically - that is, something pushes data towards your file handle, without you having to do anything. Non-blocking means that if your operating system currently has no data (or EOF, or some error) available for you, it will not wait (``block'') as it would normally do, but immediately return with an error (e.g. "EWOULDBLOCK" - ``I would have blocked, but you forbid it'').
Your program can then wait for data to arrive by other means, for example, an I/O watcher which tells you when to re-attempt the read, after which it can try to read again, and so on.
Often, you would expect this to work for disk files as well - if the data isn't already in memory, one might want to wait for it and then re-attempt the read for example. While this is sound reasoning, the POSIX API does not support this, because disk drives and file systems do not send data ``on their own'', and more so, the OS already knows that data is there, it doesn't need to ``wait'' until it arrives from some external entity, it only needs to transfer the data from disk to your memory buffer.
So basically, while the concept is sound, the existing OS APIs do not support this. Therefore, it makes no sense to switch a disk file handle into non-blocking mode - it will behave exactly the same as in blocking mode, namely it will block until the data has been read from the disk.
The alternative to non-blocking I/O that actually works with disk files is usually called asynchronous I/O. Asynchronous, because the actual I/O is done while your program does something else: there is no need to call the read function to see if data is there, you only order the read once, and it will notify you when the read has finished and the data is your buffer - all the work is done in the background.
This works with disk files, and even with sockets and other sources. It is, however, not very efficient when used with sources that could be driven in a non-blocking way, because it usually has higher overhead in the OS than non-blocking I/O, because it ties memory buffers for a potentially unlimited time and often only a limited number of operations can be done in parallel.
That's why asynchronous I/O makes most sense when confronted with disk files, and non-blocking I/O only makes sense with sockets, pipes and similar streaming sources.
:aio all aio_* functions, same as :DEFAULT :flags the fcntl open flags (O_CREAT, O_RDONLY, ...)
This makes all of the following forms of error checking valid:
aio_open ...., sub {
my $fh = shift # scalar assignment - will assign undef on error
or return AE::log error => "...";
my ($fh) = @_ # list assignment - will be 0 elements on error
or return AE::log error => "...";
@_ # check the number of elements directly
or return AE::log error => "...";
use AnyEvent::IO;
aio_stat "path1", sub {
aio_stat "path2", sub {
warn "both stats done\n";
};
};
Starts a "stat" operation and then exits by ``falling off the end'' of the program. Nevertheless, both "stat" operations will be executed, as AnyEvent::IO waits for all outstanding requests to finish and you can start new requests from request callbacks.
In fact, since AnyEvent::IO::Perl is currently synchronous, the program will do both stats before falling off the end, but with AnyEvent::IO::IOAIO, the program first falls of the end, then the stats are executed.
While not guaranteed, this behaviour will be present in future versions, if reasonably possible (which is extreemly likely :).
Example: load /etc/hosts.
aio_load "/etc/hosts", sub {
my ($hosts) = @_
or return AE::log error => "/etc/hosts: $!";
AE::log info => "/etc/hosts contains ", ($hosts =~ y/\n/), " lines\n";
};
The (normal, standard, perl) file handle associated with the opened file is then passed to the callback.
This works very much like Perl's "sysopen" function.
Changing the "umask" while this request executes results in undefined behaviour - likewise changing anything else that would change the outcome, such as your effective user or group ID.
To avoid having to load Fcntl, this module provides constants for "O_RDONLY", "O_WRONLY", "O_RDWR", "O_CREAT", "O_EXCL", "O_TRUNC" and "O_APPEND" - you can either access them directly ("AnyEvent::IO::O_RDONLY") or import them by specifying the ":flags" import tag (see SYNOPSIS).
Example: securely open a file in /var/tmp, fail if it exists or is a symlink.
use AnyEvent::IO qw(:flags);
aio_open "/var/tmp/mytmp$$", O_CREAT | O_EXCL | O_RDWR, 0600, sub {
my ($fh) = @_
or return AE::log error => "$! - denial of service attack?";
# now we have $fh
};
Due to idiosyncrasies in perl, instead of calling "close", the file handle might get closed by "dup2"'ing another file descriptor over it, that is, the $fh might still be open, but can be closed safely afterwards and must not be used for anything.
Example: close a file handle, and dirty as we are, do not even bother to check for errors.
aio_close $fh, sub { };
If less than $length octets have been read, $data will contain only those bytes actually read. At EOF, $data will be a zero-length string. If an error occurs, then nothing is passed to the callback.
Obviously, multiple "aio_read"'s or "aio_write"'s at the same time on file handles sharing the underlying open file description results in undefined behaviour, due to sharing of the current file offset (and less obviously so, because OS X is not thread safe and corrupts data when you try).
Example: read 128 octets from a file.
aio_read $fh, 128, sub {
my ($data) = @_
or return AE::log error "read from fh: $!";
if (length $data) {
print "read ", length $data, " octets.\n";
} else {
print "EOF\n";
}
};
The resulting absolute offset will be passed to the callback on success.
Example: measure the size of the file in the old-fashioned way using seek.
aio_seek $fh, 0, 2, sub {
my ($size) = @_
or return AE::log error => "seek to end failed: $!";
# maybe we need to seek to the beginning again?
aio_seek $fh, 0, 0, sub {
# now we are hopefully at the beginning
};
};
If less than "length $data" octets have been written, $length will reflect that. If an error occurs, then nothing is passed to the callback.
Obviously, multiple "aio_read"'s or "aio_write"'s at the same time on file handles sharing the underlying open file description results in undefined behaviour, due to sharing of the current file offset (and less obviously so, because OS X is not thread safe and corrupts data when you try).
Example: truncate /etc/passwd to zero length - this only works on systems that support "truncate", should not be tried out for obvious reasons and debian will probably open yte another security bug about this example.
aio_truncate "/etc/passwd", sub {
@_
or return AE::log error => "/etc/passwd: $! - are you root enough?";
};
The special case of both $atime and $mtime being "undef" sets the times to the current time, on systems that support this.
Example: try to touch file.
aio_utime "file", undef, undef, sub { };
If $uid or $gid can be specified as "undef", in which case the uid or gid of the file is not changed. This differs from Perl's "chown" built-in, which wants "-1" for this.
Example: update the group of file to 0 (root), but leave the owner alone.
aio_chown "file", undef, 0, sub {
@_
or return AE::log error => "chown 'file': $!";
};
Example: change file to be user/group/world-readable, but leave the other flags alone.
aio_stat "file", sub {
@_
or return AE::log error => "file: $!";
aio_chmod "file", (stat _)[2] & 07777 | 00444, sub { };
};
The stat data will be available by "stat"'ing the "_" file handle (e.g. "-x _", "stat _" and so on).
Example: see if we can find the number of subdirectories of /etc.
aio_stat "/etc", sub {
@_
or return AE::log error => "/etc: $!";
(stat _)[3] >= 2
or return AE::log warn => "/etc has low link count - non-POSIX filesystem?";
print "/etc has ", (stat _)[3] - 2, " subdirectories.\n";
};
Example: link "file to file.bak, then rename file.new over file, to atomically replace it.
aio_link "file", "file.bak", sub {
@_
or return AE::log error => "file: $!";
aio_rename "file.new", "file", sub {
@_
or return AE::log error => "file.new: $!";
print "file atomically replaced by file.new, backup file.bak\n";
};
};
Example: create a symlink "slink containing ``random data''.
aio_symlink "random data", "slink", sub {
@_
or return AE::log error => "slink: $!";
};
Example: read the symlink called Fyslink> and verify that it contains ``random data''.
aio_readlink "slink", sub {
my ($target) = @_
or return AE::log error => "slink: $!";
$target eq "random data"
or AE::log critical => "omg, the world will end!";
};
See "aio_link" for an example.
Example: try to delete the file tmpfile.dat~.
aio_unlink "tmpfile.dat~", sub { };
Example: try to create the directory subdir and leave it to whoeveer comes after us to check whether it worked.
aio_mkdir "subdir", 0777, sub { };
Example: try to remove the directory subdir and don't give a damn if that fails.
aio_rmdir "subdir", sub { };
The ordering of the file names is undefined - backends that are capable of it (e.g. IO::AIO) will return the ordering that most likely is fastest to "stat" through, and furthermore put entries that likely are directories first in the array.
If you need best performance in recursive directory traversal or when looking at really big directories, you are advised to use IO::AIO directly, specifically the "aio_readdirx" and "aio_scandir" functions, which have more options to tune performance.
Example: recursively scan a directory hierarchy, silently skip diretcories we couldn't read and print all others.
sub scan($); # visibility-in-next statement is not so useful these days
sub scan($) {
my ($path) = @_;
aio_readdir $path, sub {
my ($names) = @_
or return;
print "$path\n";
for my $name (@$names) {
aio_lstat "$path/$name", sub {
scan "$path/$name"
if -d _;
};
}
};
}
scan "/etc";
Marc Lehmann <schmorp@schmorp.de> http://anyevent.schmorp.de